## ◆これ何？
##  合同スレのエントリー者の一覧をwikiの形式に一発で変換するツール。
##  毎日弄るの面倒だし、と手抜きをしたくて手間をかけて作成。本末転倒すぎる
##  製作期間１時間半（一部、個人用の同系統ツールの内容を流用）
##  
##  基本的に、処理は一通り対応してるけど、現在未対応は以下の２点。
##  取り敢えず【2:56 2011/01/24】時点では全部で片手で数えられる範囲なので、手動で訂正すべし。
##  ・（仮）表記（及び、名前での括弧の使用）
##  ・エントリー時の注釈
##  

プロローグ:
## ◆読込ファイルを選択
AutoTalk システム
読込ファイルを選択ｾﾖ
End
Set 変換前 LoadFileDialog("テキストファイル","txt","","エントリー内容コピペ")
If 変換前 = "" Exit

Set 元ファイル名 Mid(変換前,InStr(変換前,"\") + 1)


## ◆エントリー内容コピペからデータを読込、変換【ＰＣ用】
Set 人数 0
Set 偶奇 0
Set いろ ""
Set 所属 ""
Open 変換前 For 入力 As Mae
  Do While (Not EOF(Mae))
    LineRead Mae 内容
    Switch Left(内容,2)
    Case ""
    Case "合計"
      Set 人数 内容
    Case "正義"
      Set 所属 "正"
      Set いろ "BGCOLOR(#DDDDFF):"
      Set 偶奇 0
      Set 参加者["正",0] "|>|>|>|>|BGCOLOR(#8080FF):$(内容)|"
    Case "中立"
      Set 所属 "中"
      Set いろ "BGCOLOR(#FFFFBB):"
      Set 偶奇 0
      Set 参加者["中",0] "|>|>|>|>|BGCOLOR(#FFFF80):$(内容)|"
    Case "悪："
      Set 所属 "悪"
      Set いろ "BGCOLOR(#606060):COLOR(#FFFFFF):"
      Set 偶奇 0
      Set 参加者["悪",0] "|>|>|>|>|BGCOLOR(#404040):COLOR(#FFFFFF):$(内容)|"
    Case Else
      Set 偶奇 (偶奇 * -1 + 1)
      If 偶奇 Then
        Incr Line[所属]
        Set 参加者[所属,Line[所属]] "|$(いろ)$(Left(Mid(内容,2),InStr(内容,"（") - 2))|$(いろ)$(Left(Mid(内容,InStr(内容,"（") + 1),InStr(Mid(内容,InStr(内容,"（") + 1),"）") - 1))|BGCOLOR(#000000):"
      Else
        Set 参加者[所属,Line[所属]] "$(参加者[所属,Line[所属]])|$(いろ)$(Left(Mid(内容,2),InStr(内容,"（") - 2))|$(いろ)$(Left(Mid(内容,InStr(内容,"（") + 1),InStr(Mid(内容,InStr(内容,"（") + 1),"）") - 1))|"
      Endif
    Endsw
  Loop
Close Mae

## ◆ちゃんと悪まで到達しなかった場合、エラー判定
If 所属 <> "悪" Then
  AutoTalk システム
  エラーが発生。.処理を中断し終了。
  End
  Exit
Endif

## ◆エントリー内容コピペからデータを読込、変換【携帯用】
Set 所属ｋ ""
Open 変換前 For 入力 As Mae2
  Do While (Not EOF(Mae))
    LineRead Mae2 内容
    Switch Left(内容,2)
    Case ""
    Case "合計"
    Case "正義"
      Set 所属ｋ "正"
      Set 参加者ｋ["正",0] "&bold(){◆$(内容)}"
    Case "中立"
      Set 所属ｋ "中"
      Set 参加者ｋ["中",0] "&bold(){◆$(内容)}"
    Case "悪："
      Set 所属ｋ "悪"
      Set 参加者ｋ["悪",0] "&bold(){◆$(内容)}"
    Case Else
      Incr Line_k[所属ｋ]
      Set 参加者ｋ[所属ｋ,Line_k[所属ｋ]] "-$(Mid(内容,2))"
    Endsw
  Loop
Close Mae2


## ◆保存先の名前を選択
AutoTalk システム
保存ファイル名を決ﾒﾖ
End
Set 変換後 SaveFileDialog("テキストファイル","txt","$(元ファイル名)_変換版")
If 変換後 = "" Exit

## ◆データを書込
Open 変換後 For 出力 As Ato
Print Ato ""
Print Ato "&big(){&bold(){　$(人数)}}（$(Month(Now))月$(Day(Now))日 $(Format(Hour(Now),00)):$(Format(Minute(Now),00))時点）"
Print Ato ""

Print Ato "#exk(){"
For i = 0 To Line[正]
  Print Ato 参加者[正,i]
Next
Print Ato ""
For i = 0 To Line[中]
  Print Ato 参加者[中,i]
Next
Print Ato ""
For i = 0 To Line[悪]
  Print Ato 参加者[悪,i]
Next
Print Ato "}"

Print Ato "#exp(){"
For i = 0 To Line_k["正"]
  Print Ato 参加者ｋ["正",i]
Next
For i = 0 To Line_k["中"]
  Print Ato 参加者ｋ["中",i]
Next
For i = 0 To Line_k[悪]
  Print Ato 参加者ｋ["悪",i]
Next
Print Ato "}"

Close Ato

AutoTalk システム
データ作成完了
End

スタート:
RemoveFile "_リスタート.src"
Quit